Initial commit

2026-11-01 07:23:51 +01:00
commit 8d55bb8a2f
17 changed files with 1679 additions and 0 deletions
@@ -0,0 +1,115 @@
+/*
+ *   This file is a part of the SteamWar software.
+ *
+ *   Copyright (C) 2025 SteamWar.de-Serverteam
+ *
+ *   This program is free software: you can redistribute it and/or modify
+ *   it under the terms of the GNU Affero General Public License as published by
+ *   the Free Software Foundation, either version 3 of the License, or
+ *   (at your option) any later version.
+ *
+ *   This program is distributed in the hope that it will be useful,
+ *   but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+ *   GNU Affero General Public License for more details.
+ *
+ *   You should have received a copy of the GNU Affero General Public License
+ *   along with this program.  If not, see <https://www.gnu.org/licenses/>.
+ */
+
+import org.apache.tools.ant.taskdefs.condition.Os
+import java.net.URI
+import java.util.*
+
+pluginManagement {
+    plugins {
+        kotlin("plugin.lombok") version "2.3.20"
+    }
+}
+
+rootProject.name = "ViaAxiom"
+
+private val isInCi by lazy { Os.isFamily(Os.FAMILY_UNIX) && ProcessBuilder("hostname").start().inputStream.bufferedReader().readText().startsWith("steamwar.de") }
+
+dependencyResolutionManagement {
+    repositories {
+        maven {
+            url = URI("https://m2.dv8tion.net/releases")
+            content {
+                includeGroup("net.dv8tion")
+            }
+        }
+
+        maven {
+            url = URI("https://maven.enginehub.org/repo")
+            content {
+                includeGroup("com.sk89q.worldedit")
+                includeGroup("com.sk89q.worldedit.worldedit-libs")
+            }
+        }
+
+        maven {
+            if (isInCi) {
+                url = URI("file:///var/www/maven/")
+            } else {
+                url = URI("https://maven.steamwar.de/")
+                credentials {
+                    val swProps = Properties()
+                    swProps.load(rootDir.resolve("steamwar.properties").inputStream())
+
+                    username = swProps.getProperty("maven.username")
+                    password = swProps.getProperty("maven.password")
+                }
+            }
+
+            content {
+                includeGroup("de.steamwar")
+            }
+        }
+
+        maven {
+            url = URI("https://repo.codemc.io/repository/maven-snapshots/")
+            content {
+                includeGroup("net.wesjd")
+            }
+        }
+
+        maven {
+            url = URI("https://libraries.minecraft.net")
+            content {
+                includeGroup("com.mojang")
+            }
+        }
+
+        maven {
+            url = URI("https://repo.viaversion.com")
+            content {
+                includeGroup("com.viaversion")
+            }
+        }
+
+        maven {
+            url = URI("https://repo.papermc.io/repository/maven-public/")
+            content {
+                includeGroup("org.bukkit")
+                includeGroup("org.spigotmc")
+                includeGroup("io.papermc.paper")
+                includeGroup("com.velocitypowered")
+                includeGroup("net.md-5")
+            }
+        }
+        mavenCentral()
+    }
+
+    versionCatalogs {
+        create("libs") {
+            plugin("shadow", "com.github.johnrengelman.shadow").version("8.1.1")
+            library("lombok", "org.projectlombok:lombok:1.18.32")
+            library("axiom", "de.steamwar:axiompaper:RELEASE")
+            library("velocity", "de.steamwar:velocity:RELEASE")
+            library("velocityapi", "com.velocitypowered:velocity-api:3.5.0-SNAPSHOT")
+            library("viaapi", "com.viaversion:viaversion-api:4.3.1")
+            library("viavelocity", "com.viaversion:viaversion-velocity:4.3.1")
+        }
+    }
+}